大阪市の施設情報・防災情報のLOD

第1回Linked Open Dataハッカソン関西 in 大阪の「データソン」で，大阪市よりご提供頂いたデータをLOD化したものを公開するためのページです．
データのRDF（LOD）化には，LinkData.orgを利用させて頂きました．

元データ

大阪市より「Linked Open Dataハッカソン関西 in 大阪」向けにご提供頂いた，マップナビおおさかに掲載されている施設情報等のデータ（CSVファイル等）を元データとしています．

LOD化したデータ

LOD（RDF）化したデータは，下記の通りです．

SPAQRLエンドポイント

上記のLODを格納したSPAQRLエンドポイントへは，下記からアクセスできます．
http://lod.hozo.jp/repositories/OsakaCityMap

ライセンス

上記のLOD化したデータは，はクリエイティブ・コモンズ・ライセンス（CC-BY）で公開しています．
データを利用する際は原作者のクレジット（Linked Open Dataハッカソン関西in大阪，大阪市）を表示するようにしてください．


各データで用いているプロパティの一覧，および，検索例（SPARQLスニペット）

施設情報

プロパティ名(URI) データ型 説明 補足事項
http://schema.org/name リテラル(@ja) 施設名 rdfs:labelにはラベルが入っているため，
「施設名」を取得する際には，こちらをご利用ください．
http://lodosaka.hozo.jp/ku リテラル(@ja) 区 下記のいずれかの値が入ります．
"阿倍野区","旭区","港区","此花区","住吉区", "住之江区","城東区","生野区","西区","西成区", "西淀川区","大正区","中央区","鶴見区", "天王寺区","都島区","東住吉区","東成区", "東淀川区","福島区","平野区","北区", "淀川区","浪速区","大阪市以外"
http://schema.org/address リテラル(@ja) 住所
http://lodosaka.hozo.jp/category_1 リテラル(@ja) 大分類 下記のいずれかの値が入ります．
"官公庁","学校・保育所","公園・スポーツ","会館・ホール", "文化・観光","警察・消防","医療・福祉","名所・旧跡", "駅・バス停","駐車場・駐輪場","公衆トイレ","環境・リサイクル", "その他"
http://lodosaka.hozo.jp/category_2 リテラル(@ja) 小分類 下記のいずれかの値が入ります．※大分類との対応は上記を参照
"国の機関","府の機関","市の機関","幼稚園","保育所","小学校", "中学校","高等学校","大学","学校(その他)","スポーツ施設", "公園","児童遊園・広場","会館・ホール","地域集会所・老人憩いの家", "図書館","美術館・博物館","都市景観資源","その他施設", "警察・交番","消防署","病院・診療所","福祉施設", "特別養護老人ホーム","介護老人保健施設","社寺","名所・旧跡", "駅","バス停","バイク駐車場","駅周辺駐輪場","駅周辺駐輪場（その他）", "自転車保管所","パーク＆ライド駐車場","公衆便所", "車いす対応公衆便所","古紙回収協力店","無線LANスポット"
http://www.w3.org/2003/01/geo/wgs84_pos#lat xsd:float 緯度
http://www.w3.org/2003/01/geo/wgs84_pos#long xsd:float 経度

SPARQLスニペット

※こちらの「SPAQRLエンドポイント」のクエリ入力欄に下記のクエリをコピーして実行すると結果をご覧いただけます．

(1) 緯度・経度を持つリソースのURI，名称，緯度，経度を取得 
PREFIX schema:<http://schema.org/>
PREFIX geo:<http://www.w3.org/2003/01/geo/wgs84_pos#>
SELECT DISTINCT * WHERE{
  ?uri schema:name ?label;
  geo:lat ?lat;
  geo:long ?long.
}

(2) 「古墳」という文字列を名称に含むリソースのURI，名称，緯度，経度を取得 
PREFIX schema:<http://schema.org/>
PREFIX geo:<http://www.w3.org/2003/01/geo/wgs84_pos#>
SELECT DISTINCT * WHERE{
  ?uri schema:name ?name;
       geo:lat ?lat;
       geo:long ?long.
  FILTER regex(str(?name),"古墳")
}

(3) 「中之島」という文字列を住所に含むリソースのURI，名称，住所を取得
PREFIX schema:<http://schema.org/>
SELECT DISTINCT * WHERE{
  ?uri schema:address ?address;
  schema:name ?name.
  FILTER regex(str(?address),"中之島")
}

(4) 阿倍野区に含まれるリソースのURI，名称を取得 
PREFIX lodosaka:<http://lodosaka.hozo.jp/>
PREFIX schema:<http://schema.org/>
SELECT DISTINCT * WHERE{
  ?uri lodosaka:ku "阿倍野区"@ja;
        schema:name ?name.
}

(5) 文化・観光もしくは名所・旧跡の施設が多い区ランキングを取得 
PREFIX lodosaka:<http://lodosaka.hozo.jp/>
SELECT ?ku (COUNT(?uri) AS ?count)  WHERE{
  ?uri lodosaka:category_1 ?cat;
       lodosaka:ku ?ku.
  FILTER regex(str(?cat), "^(名所・旧跡)|(文化・観光)$")
}
GROUP BY ?ku
ORDER BY DESC(?count)

(6) 指定された範囲にあるトイレのURI，名称，緯度，経度を取得 
PREFIX schema:<http://schema.org/>
PREFIX geo:<http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX lodosaka:<http://lodosaka.hozo.jp/>
SELECT DISTINCT * WHERE{
  ?uri lodosaka:category_1 "公衆トイレ"@ja;
       schema:name ?name;
       geo:lat ?lat;
       geo:long ?long.
  FILTER (
    ?lat > 34.701 &&
     ?lat < 34.709 &&
    ?long > 135.49 &&
    ?long < 135.50
  )
}

（「Linked Open Dataハッカソン関西 in 大阪」のページへ）

問合わせ先：　lodosaka@gmail.com　（LODチャレンジ実行委員会関西支部長/大阪大学　古崎晃司）